例題７では、データが1日分でしたが、例題８では31日分のデータを読み込んで1日毎の最高気温、最低気温、平均気温を求めます。
例題８のフローチャートとプログラムの例を示します。
概要 |
 |
 |
|---|---|---|
 |
 | |
| 行 | プログラム |
|---|---|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 |
c Example 8 ２次元配列 ファイルへ出力
c 機械工学科 1年 xxxxxxx my name
c Filename = reidai08.f
integer hour, day
parameter (hour=24, day=31)
real a(hour,day),av(day),amin(day),amax(day)
data m/hour/
c 気温データを読む
open(11,file='reidai08.d',status='old')
do 1010 j=1,4
read(11,*)
1010 continue
1001 continue
read(11,101,end=2001) n,(a(i,n),i=1,m)
go to 1001
2001 continue
close(11)
c 1日毎の最高・最低気温、平均気温を求める
do 2010 j=1,n
asum=0.0
wmin=99.0
wmax=-99.0
do 2020 i=1,m
asum=asum+a(i,j)
if(a(i,j).gt.wmax) wmax=a(i,j)
if(a(i,j).lt.wmin) wmin=a(i,j)
2020 continue
av(j)=asum/real(m)
amin(j)=wmin
amax(j)=wmax
2010 continue
c 1ヶ月の最高・最低気温を求める
wmin=99.0
wmax=-99.0
do 2030 j=1,n
if(amax(j).gt.wmax) then
wmax=amax(j)
imax=j
end if
if(amin(j).lt.wmin) then
wmin=amin(j)
imin=j
end if
2030 continue
c 出力
write(*,601)
do 3010 j=1,n
write(*,602) j, amax(j), amin(j), av(j)
3010 continue
write(*,603) imax, amax(imax), imin, amin(imin)
c ファイルへ出力
open(12,file='reidai08out.d',status='new')
write(12,601)
do 3020 j=1,n
write(12,602) j, amax(j), amin(j), av(j)
3020 continue
write(12,603) imax, amax(imax), imin, amin(imin)
close(12)
stop
101 format(i2,24f4.1)
601 format( '1996年7月の東京の気温'
* /' 日 最高気温 最低気温 平均気温')
602 format(i3,3f10.1)
603 format(/' １ヶ月の最高気温',i3,'日',f5.1
* ,' 最低気温',i3,'日',f5.1)
end
|
例題８のプログラム例について説明します。
４行目から７行目は宣言文です。
４行目 integer hour, day ５行目 parameter (hour=24, day=31) ６行目 real a(hour,day),av(day),amin(day),amax(day) ７行目 data m/hour/
５行目のparameter文で、定数名hour、dayを定義し、整定数 24 に hour、整定数 31 に day と名前（定数名という）をつけています。そして、その定数名を配列宣言子の寸法の指定やdata文に使用しています。
宣言文は一般には指定する順番に決まりはありませんが、parameter文については他の宣言文との位置関係に注意してください。定数名について型宣言が必要な場合には、４行目の integer文のように、定数名を定義している parameter文より前に型宣言をしておかねばなりません。また、型宣言文やdata文の中で定数名を使用する場合には、その型宣言文やdata文より前にparameter文で定義されていなければなりません。
６行目の型宣言文では、１から hour と１から day の寸法をもつ２次元配列 a, １から day の寸法をもつ１次元配列 av, amin, amax を実数型と宣言しています。a は気温データ 24時分×31日分 を格納しておくため、av, amin, amax はそれぞれ31日分の平均気温、最低気温、最高気温を格納しておくために用意したものです。
７行目のdata文では、m に初期値として定数 hour を設定しています。
９行目から１７行目はファイルからデータを読み込む部分です。
９行目 open(11,file='reidai08.d',status='old')
９行目のopen文でデータファイル（ファイル名 reidai08.d）を装置番号11の装置につなげて開きます。ファイルの先頭には見出しなどのデータでないレコードが４レコードありますので、１０行目から１２行目で、このレコードを読み飛ばします。１１行目のread文では並びを空にしています。
１０行目 do 1010 j=1,4 １１行目 read(11,*) １２行目 1010 continue
１３行目から１６行目はファイルから１ヶ月分のデータを読み込む部分で、データの書式仕様は６０行目のformat文です。
１３行目 1001 continue
１４行目 read(11,101,end=2001) n,(a(i,n),i=1,m)
１５行目 go to 1001
１６行目 2001 continue
:
６０行目 101 format(i2,24f4.1)
１４行目のread文で1日分のデータを読み込んだら、次行の go to 文で、次のデータを読むために文番号 1001 のcontinue文に無条件に戻します。データが終わりになったらファイル終了指定子により文番号 2001 のcontinue文に制御を移します。
7月のデータは31日分ありますが、他の月のデータは31日分あるとは限りませんので、ファイル終了指定子を用いてデータ数の違いに対応できるようにしています。
read文では、書式仕様(i2,24f4.1)にしたがって、まず日にちを変数 n に i2(2桁の整数)で読み込み、次に do 並び(配列要素 a(i,n) の i について１から m(ここでは24)まで)を f4.1(４桁の幅に小数点以下１桁)で読み込みます。
１７行目のclose文でファイルを閉じます。
１７行目 close(11)
１９行目から３１行目は平均気温、最高気温、最低気温を求める部分です。「１日分の平均気温、最高気温、最低気温を求める」ことを日数分繰り返しますので、次に示すように do のループが2重の入れ子になっています。内側のループ(２３行目から２７行目)が1日分( i について１から m )、外側のループ(１９行目から３１行目)が1ヶ月分( j について１から n )です。
１９行目 do 2010 j=1,n : ２３行目 do 2020 i=1,m : ２７行目 2020 continue : ３１行目 2010 continue
次の２０行目から２７行目は1日分の平均気温を求めるための合計、最高気温、最低気温を求める部分です。この部分は、配列 a が２次元配列であること以外は例題７と同じですので説明は省きます。これを１９行目の do文と３１行目の continue文により日数分繰り返します。
２０行目 asum=0.0 ２１行目 wmin=99.0 ２２行目 wmax=-99.0 ２３行目 do 2020 i=1,m ２４行目 asum=asum+a(i,j) ２５行目 if(a(i,j).gt.wmax) wmax=a(i,j) ２６行目 if(a(i,j).lt.wmin) wmin=a(i,j) ２７行目 2020 continue
外側の doループの中の２８行目から３０行目は、求めた１日の平均気温、最高気温、最低気温をそれぞれ配列要素 av(j), amax(j), amin(j) に格納しています。
１９行目 do 2010 j=1,n : ２８行目 av(j)=asum/real(m) ２９行目 amin(j)=wmin ３０行目 amax(j)=wmax ３１行目 2010 continue
３３行目から４４行目は1ヶ月の最高気温とその日にち、最低気温とその日にちを求める部分です。
３３行目 wmin=99.0 ３４行目 wmax=-99.0 ３５行目 do 2030 j=1,n ３６行目 if(amax(j).gt.wmax) then ３７行目 wmax=amax(j) ３８行目 imax=j ３９行目 end if ４０行目 if(amin(j).lt.wmin) then ４１行目 wmin=amin(j) ４２行目 imin=j ４３行目 end if ４４行目 2030 continue
このうち最高気温とその日にちを求める部分を抜き出した部分が次です。
３４行目 wmax=-99.0 ３５行目 do 2030 j=1,n ３６行目 if(amax(j).gt.wmax) then ３７行目 wmax=amax(j) ３８行目 imax=j ３９行目 end if
最高気温の求め方は１日の最高気温の求め方と同じですが、気温だけでなくその日にち(配列要素の添え字に相当)も変数(ここではimax)に格納しておく必要があります。
最低気温とその日にちを求める部分を次に抜き出します。
３３行目 wmin=99.0 ３５行目 do 2030 j=1,n ４０行目 if(amin(j).lt.wmin) then ４１行目 wmin=amin(j) ４２行目 imin=j ４３行目 end if ４４行目 2030 continue
最低気温の求め方は１日の最低気温の求め方と同じですが、気温だけでなくその日にち(配列要素の添え字に相当)も変数(ここではimin)に格納しておく必要があります。
４６行目から５０行目は計算結果を出力する部分です。書式仕様には６１行目から６５行目のformat文を使用しています。
４６行目 write(*,601) ４７行目 do 3010 j=1,n ４８行目 write(*,602) j, amax(j), amin(j), av(j) ４９行目 3010 continue ５０行目 write(*,603) imax, amax(imax), imin, amin(imin) : ６１行目 601 format( '1996年7月の東京の気温' ６２行目 * /' 日 最高気温 最低気温 平均気温') ６３行目 602 format(i3,3f10.1) ６４行目 603 format(/' １ヶ月の最高気温',i3,'日',f5.1 ６５行目 * ,' 最低気温',i3,'日',f5.1)
まず４６行目のwrite文で見出しを出力します。このwrite文の並びはありませんが、文番号601のformat文の書式にしたがって、まず、文字列
1996年7月の東京の気温を出力してから行を変えて文字列
日 最高気温 最低気温 平均気温を出力します。次にdo文の指定により４８行目のwrite文をjについて１〜nまで繰り返します。このwrite文では、並びの j, amax(j), amin(j), av(j) を 書式
(i3,3f10.1)で出力します。５０行目のwrite文では文番号601のformat文の書式にしたがって、まず文字列１ヶ月の最高気温に続けて日にちimaxをi3で、続けて文字列 日 と 最高気温 amax(imax) を f5.1(5桁の幅に小数点以下１桁まで)出力し、同様に最低気温の日にちiminと最低気温 amin(imin) を出力します。
５２行目から５８行目は計算結果をファイルに出力する部分です。５２行目のopen文でファイル(ファイル名 reidai08out.d)を status='new' の指定により新しく作成し、装置番号12の装置につなげます。すでに reidai08out.d のファイルが存在するときにはopenエラーになります。５８行目のclose文でこのファイルを閉じます。
５２行目 open(12,file='reidai08out.d',status='new') ５３行目 write(12,601) ５４行目 do 3020 j=1,n ５５行目 write(12,602) j, amax(j), amin(j), av(j) ５６行目 3020 continue ５７行目 write(12,603) imax, amax(imax), imin, amin(imin) ５８行目 close(12)
ファイルへの出力はディスプレイへ出力する場合と同じ書式仕様を使用していますので、ファイルへの出力結果はディスプレイへの出力結果とまったく同じです。
例題８の出力結果は次のようになります。
1996年7月の東京の気温
日 最高気温 最低気温 平均気温
1 30.4 24.6 26.9
2 30.5 23.8 27.1
3 30.3 20.7 25.3
4 28.5 20.1 24.3
:
:
28 33.0 26.2 29.0
29 32.7 26.6 29.3
30 31.7 27.1 29.1
31 32.7 27.3 29.4
１ヶ月の最高気温 17日 34.4 最低気温 8日 17.4
